Aprender Excel
PT
Define como números, datas e fórmulas aparecem, para que tudo funcione como no seu próprio Excel.

Início › Funções do Excel › ARRUMAR

Função ARRUMAR no Excel: remover espaços extras

O ARRUMAR remove os espaços extras de um texto: todos os espaços do início e do fim, e os espaços duplos entre as palavras. É a primeira coisa a testar quando uma pesquisa retorna #N/D com um valor que você enxerga perfeitamente. No Excel em inglês, a função se chama TRIM.

Neste guia
  1. Sintaxe do ARRUMAR
  2. Exemplo básico
  3. Experimente você mesmo
  4. Corrigir erros de pesquisa
  5. Substituir os dados originais
  6. Espaços que ele não remove
  7. Números com espaços
  8. Mais exemplos de ARRUMAR
  9. Continue aprendendo
  10. Perguntas frequentes

Sintaxe do ARRUMAR

=ARRUMAR(texto)

Um único argumento: o texto ou a célula que você quer limpar. O ARRUMAR mantém um espaço simples entre as palavras.

Exemplo básico

ABC
1Original=ARRUMAR(A)=NÚM.CARACT(A) → NÚM.CARACT(B)
2 MangaManga7 → 5
3Banana Banana9 → 6
4Ana da SilvaAna da Silva15 → 12
=ARRUMAR(A2)

O problema são os espaços que você não vê. Use =NÚM.CARACT(A2) para contar caracteres: se "Manga" tem tamanho 7, sobram dois espaços em algum lugar.

Pratique ARRUMAR: experimente você mesmo

Ler é uma coisa, digitar é outra. Monte a fórmula abaixo passo a passo: as dicas dizem o que digitar, e você pode clicar nas células ou arrastar sobre elas para adicioná-las, igual ao Excel.

Tarefa: Limpe os espaços extras do nome, em B2: =ARRUMAR(A2)

Corrigir erros do PROCV e do CORRESP

"Manga " com um espaço no fim não corresponde a "Manga". Você pode limpar o valor procurado dentro da fórmula:

=PROCV(ARRUMAR(E2); $A$2:$C$7; 3; FALSO)

Se os espaços estão na própria tabela, limpe essa coluna uma vez (veja abaixo) em vez de usar o ARRUMAR em cada fórmula. Mais sobre isso no guia do PROCV.

Substituir os dados originais pela versão limpa

  1. Adicione uma coluna auxiliar com =ARRUMAR(A2) e copie para baixo.
  2. Copie a coluna auxiliar.
  3. Selecione a coluna original e use Colar Especial › Valores (Ctrl+Alt+V, escolha Valores e pressione Enter).
  4. Apague a coluna auxiliar.

Os espaços que o ARRUMAR não remove

Texto copiado de páginas da web costuma ter espaços não separáveis (o caractere 160). Eles parecem espaços normais, mas o ARRUMAR só remove o espaço normal (o caractere 32). Substitua-os primeiro e depois aplique o ARRUMAR:

=ARRUMAR(SUBSTITUIR(A2; CARACT(160); " "))

Para quebras de linha e outros caracteres de controle invisíveis de dados exportados, adicione o TIRAR:

=ARRUMAR(TIRAR(SUBSTITUIR(A2; CARACT(160); " ")))

Números com espaços

O ARRUMAR sempre retorna texto, mesmo que o resultado pareça um número. Para obter um número de verdade com o qual calcular, envolva-o no VALOR: =VALOR(ARRUMAR(A2))

Mais exemplos de ARRUMAR

Copie uma fórmula e troque os intervalos pelos seus dados.

O que você querFórmula
Remover também quebras de linha e caracteres ocultos=ARRUMAR(TIRAR(A2))
Espaços não separáveis copiados da web=ARRUMAR(SUBSTITUIR(A2; CARACT(160); " "))
Remover todos os espaços, inclusive entre palavras=SUBSTITUIR(A2; " "; "")
Um número com espaços de volta a número de verdade=VALOR(ARRUMAR(A2))

Perguntas frequentes

Por que o ARRUMAR não remove todos os espaços?

Os espaços que sobram provavelmente são espaços não separáveis (CARACT 160). Use =ARRUMAR(SUBSTITUIR(A2; CARACT(160); " ")).

Como removo todos os espaços, inclusive os entre as palavras?

Use o SUBSTITUIR em vez do ARRUMAR: =SUBSTITUIR(A2; " "; "") remove todos os espaços.

O ARRUMAR altera a célula original?

Não. Fórmulas nunca alteram outras células. Coloque o ARRUMAR em uma coluna auxiliar e cole os resultados por cima como valores.

Qual é a diferença entre ARRUMAR e TIRAR?

O ARRUMAR remove os espaços extras. O TIRAR remove caracteres não imprimíveis, como as quebras de linha. Os dois costumam ser usados juntos.