Aprender Excel
PT
Define como números, datas e fórmulas aparecem, para que tudo funcione como no seu próprio Excel.

Início › Funções do Excel › INDIRETO

Função INDIRETO no Excel, com exemplos

O INDIRETO transforma texto em uma referência de célula de verdade. =INDIRETO("B3") retorna o que estiver em B3. Ele fica poderoso quando você monta o texto com uma fórmula: escolha um nome de planilha, um número de linha ou um nome de intervalo a partir de uma célula, e a fórmula acompanha. No Excel em inglês, a função se chama INDIRECT.

Neste guia
  1. Sintaxe do INDIRETO
  2. Exemplo básico
  3. Experimente você mesmo
  4. Dados de outra planilha
  5. Lista suspensa dependente
  6. Desvantagens
  7. Continue aprendendo
  8. Perguntas frequentes

Sintaxe do INDIRETO

=INDIRETO(texto_ref; [a1])
ArgumentoO que significa
texto_refUma referência em forma de texto, como "B3", "Planilha2!A1" ou um intervalo nomeado.
a1
(opcional)
VERDADEIRO ou omitido para referências A1 normais; FALSO para o estilo L1C1 ("L3C2").

Exemplo básico: número da linha a partir de uma célula

ABCD
110Linha3
220
330
440
550
=INDIRETO("A" & D1)

"A" & D1 vira o texto "A3", e o INDIRETO retorna o valor de A3: 30. Mude D1 para 5 e o resultado passa a ser 50.

O mesmo truque cria um intervalo que cresce com um número:

=SOMA(INDIRETO("A1:A" & D1))

Com um 3 em D1, isto soma A1:A3: 10 + 20 + 30 = 60.

Pratique INDIRETO: experimente você mesmo

Ler é uma coisa, digitar é outra. Monte a fórmula abaixo passo a passo: as dicas dizem o que digitar, e você pode clicar nas células ou arrastar sobre elas para adicioná-las, igual ao Excel.

Tarefa: Mostre em E2 o valor da célula cujo endereço está em D2: =INDIRETO(D2)

Trazer dados de uma planilha cujo nome está em uma célula

Imagine que você tem uma planilha por mês (Jan, Fev, Mar) com o total em B10. Em uma planilha de resumo, coloque os nomes das planilhas na coluna A e use:

=INDIRETO("'" & A2 & "'!B10")

Copie para baixo e cada linha mostra o total da planilha indicada na coluna A. As aspas simples em volta do nome da planilha são necessárias quando o nome tem espaços, como 'Vendas 2026', e não atrapalham nos outros casos.

O INDIRETO é a forma comum de criar uma segunda lista suspensa que depende da primeira: escolha "Fruta" e a próxima lista mostra só frutas.

  1. Coloque cada lista na sua própria coluna, com um cabeçalho: Fruta, Legume.
  2. Selecione cada lista (sem o cabeçalho) e dê um nome a ela na Caixa de Nome, exatamente igual ao cabeçalho: Fruta e Legume.
  3. Em A2, crie uma lista suspensa com a fonte Fruta;Legume (ou com vírgulas, conforme a sua configuração regional).
  4. Em B2, crie uma lista suspensa com a fonte =INDIRETO(A2)

Nomes de intervalo não podem ter espaços. Para "Laticínios e ovos", chame o intervalo de Laticínios_e_ovos e use =INDIRETO(SUBSTITUIR(A2; " "; "_"))

Desvantagens do INDIRETO

  • É volátil. O INDIRETO recalcula toda vez que qualquer coisa muda, e isso deixa pastas de trabalho grandes mais lentas.
  • As referências não se atualizam. Como a referência é texto, ela não se move quando você insere linhas ou renomeia uma planilha. Renomear "Jan" para "Janeiro" dá #REF!.
  • Não lê pastas de trabalho fechadas. Uma referência a outro arquivo só funciona enquanto esse arquivo está aberto.

Para pesquisas, ÍNDICE/CORRESP ou o PROCX costumam ser escolhas melhores. Use o INDIRETO quando o que precisa mudar é o próprio nome da planilha ou do intervalo.

Perguntas frequentes

Por que o INDIRETO retorna #REF!?

O texto não é uma referência válida: um erro de digitação no nome da planilha, faltam as aspas em volta de um nome com espaços, um intervalo nomeado que não existe ou uma referência a uma pasta de trabalho fechada.

Posso usar o INDIRETO com o nome de uma tabela?

Sim, por exemplo =SOMA(INDIRETO(A2 & "[Valor]")) com o nome da tabela em A2.

O que o INDIRETO faz com uma referência fixa?

=INDIRETO("A1") sempre aponta para A1, mesmo que você insira linhas acima. É uma forma de travar uma referência por completo, além do que o $A$1 faz.

Existe uma alternativa ao INDIRETO que não seja volátil?

O ÍNDICE não é volátil: =SOMA(A1:ÍNDICE(A:A; D1)) dá o mesmo intervalo crescente do exemplo com INDIRETO.