Home › Excel-functies › VIND.ALLES en VIND.SPEC
Tekst zoeken in een cel: VIND.ALLES en VIND.SPEC
VIND.ALLES en VIND.SPEC geven de positie van een stuk tekst in een cel. Dat is op zich al handig, maar vooral als bouwsteen: om te controleren of een cel een woord bevat, of om alles vóór of na een teken op te halen. In de Engelse Excel heten ze FIND en SEARCH.
VIND.ALLES en VIND.SPEC · In deze uitleg
Syntaxis
=VIND.ALLES(zoeken_tekst; in_tekst; [begin_getal]) =VIND.SPEC(zoeken_tekst; in_tekst; [begin_getal])Beide geven een getal: de positie van het eerste teken van de overeenkomst. =VIND.ALLES("@"; "anna@voorbeeld.nl") geeft 5. Wordt de tekst niet gevonden, dan geven beide #WAARDE!.
Het verschil
| VIND.ALLES | VIND.SPEC | |
|---|---|---|
| Hoofdlettergevoelig | Ja | Nee |
| Jokertekens (* en ?) | Nee | Ja |
"excel" in "Excel CSE" | #WAARDE! | 1 |
In de meeste gevallen wil je VIND.SPEC, omdat "Spoed" en "spoed" allebei moeten tellen.
Controleren of een cel een woord bevat
Zet VIND.SPEC in ISGETAL: een getal betekent gevonden, een fout betekent niet gevonden.
=ISGETAL(VIND.SPEC("spoed"; A2))Geeft WAAR of ONWAAR. In de ALS-functie:
=ALS(ISGETAL(VIND.SPEC("spoed"; A2)); "Voorrang"; "")Zo filter je ook op een deel van de tekst met FILTER en gebruik je "bevat" in voorwaardelijke opmaak.
Tekst vóór of na een teken ophalen
- Gebruikersnaam uit een e-mailadres:
=LINKS(A2; VIND.ALLES("@"; A2)-1)geeft "anna". - Domein:
=DEEL(A2; VIND.ALLES("@"; A2)+1; 100)geeft "voorbeeld.nl".
Zie LINKS, RECHTS en DEEL. In Microsoft 365 en Excel 2024 doen TEKST.VOOR en TEKST.NA dit zonder VIND.ALLES.
De tweede keer vinden
Gebruik begin_getal om net na de eerste treffer verder te zoeken:
=VIND.ALLES("-"; A2; VIND.ALLES("-"; A2)+1)In "P-104-NL" geeft dit 6, de positie van het tweede streepje.
Veelgestelde vragen
Waarom geeft VIND.ALLES #WAARDE!?
De tekst werd niet gevonden, mogelijk door een verschil in hoofdletters. Gebruik VIND.SPEC om zonder hoofdlettergevoeligheid te zoeken, en ALS.FOUT om ontbrekende waarden af te vangen.
Hoe controleer ik of een cel een van meerdere woorden bevat?
Combineer controles met OF: =OF(ISGETAL(VIND.SPEC("spoed"; A2)); ISGETAL(VIND.SPEC("asap"; A2))).
Kan VIND.SPEC jokertekens gebruiken?
Ja. =VIND.SPEC("fac*2026"; A2) vindt "fac" gevolgd door wat dan ook en daarna "2026".
Wat zijn VIND.ALLES en VIND.SPEC in het Engels?
FIND en SEARCH. =VIND.SPEC("spoed";A2) is in de Engelse Excel =SEARCH("spoed",A2).