Start › Excel-Funktionen › FINDEN und SUCHEN
FINDEN und SUCHEN in Excel
FINDEN und SUCHEN geben die Position zurück, an der ein Text in einer Zelle beginnt. Allein ergeben sie nur eine Zahl, aber kombiniert mit LINKS, TEIL oder ISTZAHL prüfen Sie damit, ob eine Zelle ein Wort enthält, und zerlegen Text in Teile. Im englischen Excel heißen die Funktionen FIND und SEARCH.
FINDEN und SUCHEN · In dieser Anleitung
Syntax
=FINDEN(Suchtext; Text; [Erstes_Zeichen]) =SUCHEN(Suchtext; Text; [Erstes_Zeichen])=FINDEN("@"; "anna@beispiel.de") ergibt 5. Wird der Text nicht gefunden, ergeben beide #WERT!. Mit Erstes_Zeichen beginnen Sie die Suche ab einer späteren Position.
FINDEN oder SUCHEN
| FINDEN | SUCHEN | |
|---|---|---|
| Groß-/Kleinschreibung | wird unterschieden | wird nicht unterschieden |
| Platzhalter (* und ?) | nein | ja |
=…("e"; "Excel") | 4 | 1 |
Im Zweifel nehmen Sie SUCHEN: Die meisten Prüfungen sollen nicht an der Schreibweise scheitern.
FINDEN und SUCHEN üben: selbst ausprobieren
Lesen ist das eine, selbst tippen das andere. Bauen Sie die Formel unten Schritt für Schritt auf: Die Tipps sagen Ihnen, was Sie eingeben müssen, und Sie können auf Zellen klicken oder darüber ziehen, um sie hinzuzufügen, genau wie in Excel.
Aufgabe: Finden Sie in B2 die Position des @ in der E-Mail-Adresse: =FINDEN("@";A2)
Prüfen, ob eine Zelle ein Wort enthält
Packen Sie SUCHEN in ISTZAHL. Wird das Wort gefunden, gibt SUCHEN eine Zahl zurück, also ergibt ISTZAHL WAHR:
=WENN(ISTZAHL(SUCHEN("express"; A2)); "Eilig"; "Normal")Dieselbe Bedingung funktioniert in FILTER (=FILTER(A2:C100; ISTZAHL(SUCHEN("express"; A2:A100)))) und in der bedingten Formatierung, um passende Zeilen zu markieren.
Text vor oder nach einem Zeichen extrahieren
- Vor dem @:
=LINKS(A2; FINDEN("@"; A2) - 1) - Nach dem @:
=TEIL(A2; FINDEN("@"; A2) + 1; 100)
Mehr in LINKS, RECHTS und TEIL. In Microsoft 365 ist TEXTVOR und TEXTNACH einfacher.
Das zweite Vorkommen finden
Beginnen Sie die zweite Suche direkt nach dem ersten Treffer:
=FINDEN("-"; A2; FINDEN("-"; A2) + 1)In „P-104-DE“ ergibt das 6, die Position des zweiten Bindestrichs.
Häufige Fragen
Warum gibt FINDEN #WERT! zurück?
Der Suchtext kommt nicht vor, oder die Schreibweise passt nicht (FINDEN unterscheidet Groß- und Kleinschreibung). Verwenden Sie SUCHEN oder packen Sie die Formel in WENNFEHLER.
Wie prüfe ich, ob eine Zelle eines von mehreren Wörtern enthält?
Verwenden Sie =SUMMENPRODUKT(--ISTZAHL(SUCHEN({"rot";"blau"}; A2)))>0. Das ergibt WAHR, wenn mindestens eines der Wörter vorkommt.
Akzeptiert SUCHEN Platzhalter?
Ja: ? steht für ein beliebiges Zeichen, * für eine beliebige Zeichenfolge. Um ein echtes Sternchen zu suchen, verwenden Sie ~*.