Inicio › Funciones de Excel › SUMAR.SI
Función SUMAR.SI en Excel: cómo usarla, con ejemplos
SUMAR.SI suma los números de un rango que cumplen una condición. Ventas totales de una región, gastos por encima de un importe, horas por empleado: si necesitas una suma con filtro, SUMAR.SI es la función. En el Excel en inglés, la función se llama SUMIF.
SUMAR.SI · En esta guía
Sintaxis de SUMAR.SI
=SUMAR.SI(rango; criterio; [rango_suma])| Argumento | Qué significa |
|---|---|
| rango | Las celdas que se comparan con la condición. |
| criterio | La condición, como "Norte", ">=800" o una celda como F2. |
| rango_suma (opcional) | Las celdas que se suman. Si lo omites, se suman las celdas del propio rango. |
Ejemplo básico: ventas por región
| A | B | C | |
|---|---|---|---|
| 1 | Región | Vendedor | Ventas |
| 2 | Norte | Ana | 1.200 |
| 3 | Sur | Bruno | 800 |
| 4 | Norte | Carlos | 950 |
| 5 | Este | Diana | 450 |
| 6 | Sur | Ana | 700 |
Excel revisa cada celda de A2:A6. Donde pone "Norte" (filas 2 y 4), suma las ventas de la columna C de la misma fila: 1.200 + 950 = 2.150.
El rango y el rango_suma deben tener el mismo tamaño y empezar en la misma fila, para que cada región quede alineada con su propia cifra de ventas.
Practica SUMAR.SI: pruébalo tú mismo
Leer es una cosa y escribirlo es otra. Construye la fórmula de abajo paso a paso: las pistas te dicen qué escribir, y puedes hacer clic en las celdas o arrastrar sobre ellas para añadirlas, igual que en Excel.
Tarea: Suma todo lo gastado en "Comida" en E2: =SUMAR.SI(B2:B7;"Comida";C2:C7)
Tipos de criterios
| Quieres | Fórmula | Resultado |
|---|---|---|
| Texto exacto | =SUMAR.SI(A2:A6; "Sur"; C2:C6) | 1.500 |
| Todo excepto | =SUMAR.SI(A2:A6; "<>Norte"; C2:C6) | 1.950 |
| Números de al menos 800 | =SUMAR.SI(C2:C6; ">=800") | 2.950 |
| Texto que empieza por "A" | =SUMAR.SI(B2:B6; "A*"; C2:C6) | 1.900 |
| Celdas no vacías | =SUMAR.SI(B2:B6; "<>"; C2:C6) | 4.100 |
Algunas reglas: las condiciones con un operador van entre comillas (">=800"). En el tercer ejemplo no hay rango_suma, así que SUMAR.SI suma los valores de C2:C6. El comodín * equivale a cualquier cantidad de caracteres y ? a exactamente uno.
Poner la condición en una celda
El texto escrito en la fórmula funciona, pero una referencia de celda te permite cambiar la condición sin editar la fórmula. Con "Norte" en F2:
Operadores de comparación: qué escribir
| Escribe | Significa |
|---|---|
| = | igual a |
| > | mayor que |
| < | menor que |
| >= | mayor o igual que: primero >, luego = |
| <= | menor o igual que: primero <, luego = |
| <> | distinto de: primero <, luego > |
Siempre dos teclas separadas, nunca un símbolo especial. En un criterio, pon el operador y el valor juntos entre comillas, como ">=500" o "<>Pagado" como condición.
Para combinar un operador con una celda, únelos con &. Con 800 en F3, esto suma todas las ventas de al menos 800:
Escribir ">=F3" dentro de las comillas no funciona: Excel buscaría el texto literal "F3".
SUMAR.SI.CONJUNTO: varias condiciones
Cuando necesitas más de una condición, usa SUMAR.SI.CONJUNTO. Ojo: el orden de los argumentos es distinto, el rango que se suma va primero.
=SUMAR.SI.CONJUNTO(rango_suma; rango_criterios1; criterio1; [rango_criterios2; criterio2]; …)Las ventas de Ana en la región Sur:
=SUMAR.SI.CONJUNTO(C2:C6; A2:A6; "Sur"; B2:B6; "Ana")Solo la fila 6 cumple las dos condiciones, así que el resultado es 700. Todas las condiciones de SUMAR.SI.CONJUNTO tienen que cumplirse (lógica Y). Mucha gente usa SUMAR.SI.CONJUNTO incluso con una sola condición, para recordar un único orden de argumentos. Más ejemplos en SUMAR.SI.CONJUNTO.
Errores comunes con SUMAR.SI
- El resultado es 0. El criterio no coincide con nada. Revisa los espacios de más, o si hay números guardados como texto en el rango de suma (el texto se ignora).
- El total no cuadra. El rango y el rango_suma tienen tamaños distintos o empiezan en filas distintas, así que los valores no se alinean.
- Un operador con una celda no funciona. Usa
">"&F3y no">F3" - Argumentos en mal orden en SUMAR.SI.CONJUNTO. En SUMAR.SI.CONJUNTO el rango de suma va primero; en SUMAR.SI va al final.
Preguntas frecuentes
¿Qué diferencia hay entre SUMAR.SI y SUMAR.SI.CONJUNTO?
SUMAR.SI admite una condición; SUMAR.SI.CONJUNTO, una o más. El orden de los argumentos también cambia: SUMAR.SI.CONJUNTO empieza por el rango que se suma.
¿SUMAR.SI distingue entre mayúsculas y minúsculas?
No. "norte", "Norte" y "NORTE" se tratan igual.
¿Cómo sumo con una condición O?
Suma dos SUMAR.SI: =SUMAR.SI(A2:A6; "Norte"; C2:C6) + SUMAR.SI(A2:A6; "Sur"; C2:C6) da el total de las dos regiones.
¿Puede SUMAR.SI sumar entre dos fechas?
Usa SUMAR.SI.CONJUNTO con dos condiciones sobre la misma columna de fechas: =SUMAR.SI.CONJUNTO(C2:C100; A2:A100; ">="&F1; A2:A100; "<="&F2), con la fecha inicial en F1 y la final en F2.