Start › Excel-Funktionen › TEXTVOR und TEXTNACH
TEXTVOR und TEXTNACH in Excel
TEXTVOR gibt den Text vor einem Trennzeichen zurück und TEXTNACH den Text danach. Sie ersetzen die alten Kombinationen aus LINKS/FINDEN und TEIL/FINDEN durch eine einzige, gut lesbare Funktion. Im englischen Excel heißen die Funktionen TEXTBEFORE und TEXTAFTER.
TEXTVOR und TEXTNACH · In dieser Anleitung
Verfügbarkeit: Microsoft 365, Excel 2024 und Excel für das Web. In älteren Versionen verwenden Sie LINKS und TEIL mit FINDEN.
Syntax
=TEXTVOR(Text; Trennzeichen; [Instanznummer]; [Übereinstimmungsmodus]; [Ende_Übereinstimmung]; [falls_nicht_gefunden]) =TEXTNACH(Text; Trennzeichen; [Instanznummer]; [Übereinstimmungsmodus]; [Ende_Übereinstimmung]; [falls_nicht_gefunden])| Argument | Bedeutung |
|---|---|
| Text | Der Text oder die Zelle, die Sie aufteilen wollen. |
| Trennzeichen | Das Zeichen oder der Text, an dem geteilt wird, etwa " " oder "@". |
| Instanznummer | Welches Vorkommen: 1 ist das erste (Standard), 2 das zweite, -1 das letzte. |
| Übereinstimmungsmodus | 0 = unterscheidet Groß- und Kleinschreibung (Standard), 1 = unterscheidet sie nicht. |
| Ende_Übereinstimmung | Behandelt das Textende als Trennzeichen (selten nötig). |
| falls_nicht_gefunden | Was zurückgegeben wird, wenn das Trennzeichen fehlt. Standard ist #NV. |
Beispiele
| Ziel | Formel (A2 = „anna.mueller@beispiel.de“) | Ergebnis |
|---|---|---|
| Benutzername | =TEXTVOR(A2; "@") | anna.mueller |
| Domain | =TEXTNACH(A2; "@") | beispiel.de |
| Vorname | =TEXTVOR(A2; ".") | anna |
| Top-Level-Domain | =TEXTNACH(A2; "."; -1) | de |
TEXTVOR und TEXTNACH üben: selbst ausprobieren
Lesen ist das eine, selbst tippen das andere. Bauen Sie die Formel unten Schritt für Schritt auf: Die Tipps sagen Ihnen, was Sie eingeben müssen, und Sie können auf Zellen klicken oder darüber ziehen, um sie hinzuzufügen, genau wie in Excel.
Aufgabe: Holen Sie in B2 den Teil der E-Mail-Adresse vor dem @: =TEXTVOR(A2;"@")
Vor- und Nachnamen
Mit „Anna Maria von Berg“ in A2:
=TEXTVOR(A2; " ")ergibt Anna (vor dem ersten Leerzeichen).=TEXTNACH(A2; " ")ergibt Maria von Berg (nach dem ersten Leerzeichen).=TEXTNACH(A2; " "; -1)ergibt Berg (nach dem letzten Leerzeichen).
Wenn das Trennzeichen fehlt
Ein Name ohne Leerzeichen ergibt #NV. Verwenden Sie das letzte Argument, um etwas anderes zurückzugeben, etwa die ganze Zelle:
=TEXTVOR(A2; " "; ; ; ; A2)In mehrere Zellen aufteilen: TEXTTEILEN
Um einen Text auf einmal in alle Teile zu zerlegen, verwenden Sie TEXTTEILEN: =TEXTTEILEN("P-104-DE"; "-") lässt P, 104 und DE in drei Zellen überlaufen. Lesen Sie auch Text in Spalten und Blitzvorschau.
Häufige Fragen
Warum gibt TEXTVOR #NV zurück?
Das Trennzeichen steht nicht im Text. Geben Sie einen Wert für falls_nicht_gefunden an, oder prüfen Sie, ob Leerzeichen zu viel sind oder fehlen.
Wie erhalte ich das letzte Wort einer Zelle?
Verwenden Sie =TEXTNACH(A2; " "; -1).
Kann ich mehrere Trennzeichen verwenden?
Ja, geben Sie mehrere auf einmal an, zum Beispiel einen Bereich mit „-“ in D1 und „/“ in D2: =TEXTVOR(A2; D1:D2) teilt am ersten, das vorkommt.
Gibt es TEXTVOR in Excel 2021?
Nein. Es gibt sie in Microsoft 365, Excel 2024 und Excel für das Web.